Page 1 of 2 12 LastLast
Results 1 to 15 of 18
  1. #1
    JNL0122 is offline Novice
    Windows 10 Office 365
    Join Date
    Jan 2022
    Posts
    8

    this should have been simple but...28 day reporting periods. Need a function or 2

    My company uses 28 day periods for reporting various data. So we have 13 periods in any given year.

    Data is any table or query with a date column with dates stretching back any number of years.
    I want to make a form which while allowing my users to select any date range they wish, will also contain some presets.
    I envision 2 combo box controls that will allow selection of a start date and end date from any report, (these would be defaulted to the current date being the end date and current date - 7 being the stating date.)
    Below the 2 combo boxes would be 2 buttons titled "Current Period to Date" and "Previous Period", both of which could be used to update the values in the combo controls to the appropriate dates and finally I would like to use a 13 button Option Control with each button named Period 1 through 13 to also update the combo box controls with the appropriate dates.

    Just by chance, period 1 began on Jan. 01 this year.

    In case I am not clear what I am trying to achieve, here is a chart :

    Period 1 Starts on 1/2/2021 and Ends on 1/29/2021.
    Period 2 Starts on 1/30/2021 and Ends on 2/26/2021.


    Period 3 Starts on 2/27/2021 and Ends on 3/26/2021.
    Period 4 Starts on 3/27/2021 and Ends on 4/23/2021.
    Period 5 Starts on 4/24/2021 and Ends on 5/21/2021.
    Period 6 Starts on 5/22/2021 and Ends on 6/18/2021.
    Period 7 Starts on 6/19/2021 and Ends on 7/16/2021.
    Period 8 Starts on 7/17/2021 and Ends on 8/13/2021.
    Period 9 Starts on 8/14/2021 and Ends on 9/10/2021.
    Period 10 Starts on 9/11/2021 and Ends on 10/8/2021.
    Period 11 Starts on 10/9/2021 and Ends on 11/5/2021.
    Period 12 Starts on 11/6/2021 and Ends on 12/3/2021.
    Period 13 Starts on 12/4/2021 and Ends on 12/31/2021.
    Period 1 Starts on 1/1/2022 and Ends on 1/28/2022.
    Period 2 Starts on 1/29/2022 and Ends on 2/25/2022.
    Period 3 Starts on 2/26/2022 and Ends on 3/25/2022.
    Period 4 Starts on 3/26/2022 and Ends on 4/22/2022.
    Period 5 Starts on 4/23/2022 and Ends on 5/20/2022.
    Period 6 Starts on 5/21/2022 and Ends on 6/17/2022.
    Period 7 Starts on 6/18/2022 and Ends on 7/15/2022.
    Period 8 Starts on 7/16/2022 and Ends on 8/12/2022.
    Period 9 Starts on 8/13/2022 and Ends on 9/9/2022.
    Period 10 Starts on 9/10/2022 and Ends on 10/7/2022.
    Period 11 Starts on 10/8/2022 and Ends on 11/4/2022.
    Period 12 Starts on 11/5/2022 and Ends on 12/2/2022.
    Period 13 Starts on 12/3/2022 and Ends on 12/30/2022.

    So I am trying to code a function or if need be, more than 1 function that will take any given date, and determine what period that date falls into, (or fell into) and the Start and End dates of that period.

    What I have below in this code works sort of, but its limitations make it less than ideal. I could not have imagined that this little project would stump me like this. I am self taught and still very much learning to code so I have no illusions about my abilities, but really, 13 28 day periods in a year. How hard could that be?a Apparently beyond me. A quick search on the internet and I should have some code to make this work. Nope, I could not find anything.


    I really could use some guidance here

    Thank you in advance.
    Joe


    Code:
    Public Function FPrd(ByVal Pdnum As Variant) As Collection
         
         Dim var As Collection
         Dim FyrStrt As Date
         Dim FyrEnd As Date
         Dim StDte As Date
         Dim EdDte As Date
         
         
        Set var = New Collection
         
         FyrStrt = #1/1/2022#
         FyrStrt = DateAdd("d", -1 * (28 * 13), FyrStrt)
         FyrEnd = DateAdd("d", -1, FyrStrt)
          Pdnum = Pdnum - 1
         StDte = DateAdd("d", (28 * Pdnum), FyrStrt)
         EdDte = DateAdd("d", 27, StDte)
       
        var.Add StDte
        var.Add EdDte
        
        Set FPrd = var
        
         
         
    End Function
    
    Public Function findperiod(fdate As Date) As Long
    
    
    Dim Period As Collection
    Dim dfltLowLmt As Date
    Dim dfltUpLmt As Date
    Dim Prd As Long
    Dim Pd As Long
    
    
    
        For Prd = 1 To 26
        Set Period = FPrd(Prd)
         If IsBetween(fdate, Period.Item(1), Period.Item(2)) Then
            Pd = IIf(Prd > 13, Prd - 13, Prd)
            'Pd = Prd
                    findperiod = Pd
            Exit Function
        End If
        Next Prd
        
       
       End Function
       
    Public Function IsBetween(Val As Variant, Optional LowLmt As Variant, Optional Uplmt As Variant) As Boolean
           ' If (IsMissing(LowLmt)) Then LowLmt = dfltLowLmt
           ' If (IsMissing(Uplmt)) Then Uplmt = dfltUpLmt
            IsBetween = (LowLmt <= Val And Val <= Uplmt)
    End Function
    
    Private Sub TestDates()
        Dim Period As Collection
        
       For Prd = 1 To 26
       'If Prd = 0 Then GoTo skip2line
            
        Set Period = FPrd(Prd)
       Pd = IIf(Prd > 13, Prd - 13, Prd)
       
        Debug.Print "Period " & Pd & " Starts on " & Period.Item(1) & " and Ends on " & Period.Item(2) & "."
       ' Debug.Print Period.Item(2)
    skip2line:
       Next Prd
      
      End Sub
       
     Private Sub testsub1()
    Dim Dte As Date
    
     Dte = #1/31/2022#
    
    ' What 28 day period are we in?
       iCurPrd = findperiod(Dte)
       Debug.Print iCurPrd
    ' When did this period start?
        dCurStPrd = FPrd(findperiod(Dte)).Item(1)
    ' When did this period end?
        dCurEndPrd = FPrd(findperiod(Dte)).Item(2)
      Debug.Print dCurStPrd & " to " & dCurEndPrd
      
    ' What was the previous period?
        iprevprd = findperiod(Dte - 28)  ' Zero is not a valid entry
        'Debug.Print iprevprd
        
    ' if the response is 0 , then the answer is 13 from the previous year
        'iprevprd = IIf(iCurPrd - 13 = 0, 13, iCurPrd - 13)
    'BUT what Period 13?? The non-existant one in the Currrent year or last years
        Debug.Print iprevprd
        Debug.Print FPrd(iprevprd).Item(1) & " To " & FPrd(iprevprd).Item(2)
        
     End Sub
    
       'well this is not working,. We change period 14 to period 1 and it then gives the
       ' start and ending dates for period 1 which is actually current period - 13

  2. #2
    Join Date
    Jan 2017
    Location
    Swansea,South Wales,UK
    Posts
    4,858
    I would use a combo for your 13 periods?
    Perhaps get the data for the current year from a table that holds the periods? What if you want the previous period from last year today?
    Please use # icon on toolbar when posting code snippets.
    Cross Posting: https://www.excelguru.ca/content.php?184
    Debugging Access: https://www.youtube.com/results?sear...bug+access+vba

  3. #3
    orange's Avatar
    orange is offline Moderator
    Windows 10 Office 365
    Join Date
    Sep 2009
    Location
    Ottawa, Ontario, Canada; West Palm Beach FL
    Posts
    16,716
    Along the lines of Paul's comment, could you have a table with
    period StartDate PeriodEnd

    for as many years as practical (5 back/5 future)
    Code:
    Sub ReportingPeriods()
    'skeleton to populate a table with
    '28 day reporting periods from 2017 to 2027
        Dim StartDate  As Date
        Dim Periodlen As Integer
        Dim periodEnd As Date
        StartDate = #1/2/2017#
        Periodlen = 27
        Dim i As Integer
        i = 1
        Do Until StartDate > #12/30/2027#
            periodEnd = DateAdd("d", Periodlen, StartDate)
            Debug.Print i, StartDate, periodEnd                          'for testing  (could write to a table)
            StartDate = periodEnd + 1
            i = i + 1
            If i > 13 Then i = 1
        Loop
    End Sub

    Updated the code and included a query:

    Create a table:
    Code:
    Sub ReportingPeriods()
        On Error GoTo ReportingPeriods_Error
        'skeleton to populate a table with
        '28 day reporting periods from 2017 to 2027
        Dim cSQL As String, Cinsert As String
        'On Error Resume Next
        CurrentDb.Execute "drop table TblReportingPeriods;"
        cSQL = "Create Table TblReportingPeriods (" _
            & "PK AUTOINCREMENT PRIMARY KEY" _
            & ",Period integer " _
            & ",StartDate  Date  " _
            & ",PeriodEnd Date " _
            & ",constraint UX_Start unique(StartDate ) " _
            & ");"
       Cinsert = "INSERT INTO TblReportingPeriods(Period,StartDate,PeriodEnd) VALUES("
    
        Debug.Print cSQL
     
        CurrentDb.Execute cSQL, dbFailOnError
      
        Dim StartDate  As Date
        
        Dim Periodlen As Integer
        Dim periodEnd As Date
        StartDate = #1/2/2017#
        Periodlen = 27
        Dim i As Integer
        i = 1
        Do Until StartDate > #12/30/2027#
            periodEnd = DateAdd("d", Periodlen, StartDate)
            Debug.Print i, StartDate, periodEnd
            Debug.Print Cinsert & i & ",#" & StartDate & "#,#" & periodEnd & "#)"
            CurrentDb.Execute Cinsert & i & ",#" & StartDate & "#,#" & periodEnd & "#)", dbFailOnError
            StartDate = periodEnd + 1
            i = i + 1
            If i > 13 Then i = 1
        Loop
        
        On Error GoTo 0
    ReportingPeriods_Exit:
        Exit Sub
    
    ReportingPeriods_Error:
    
        MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure ReportingPeriods, line " & Erl & "."
        GoTo ReportingPeriods_Exit
    End Sub
    Query:
    PARAMETERs myDateMMDDYYYY date;
    SELECT Period,TblReportingPeriods.StartDate, TblReportingPeriods.PeriodEnd
    FROM TblReportingPeriods
    where startDate <=myDateMMDDYYYY and PeriodEnd>= myDateMMDDYYYY

  4. #4
    Micron is offline Virtually Inert Person
    Windows 10 Access 2016
    Join Date
    Jun 2014
    Location
    Ontario, Canada
    Posts
    12,737
    maybe take the span from 01/02/2022 to the end date rather than have multiple periods that are the same.
    round(DateDiff("d",#01/02/2022#,#06/18/2022#)/28,0) gives period 6. Rounding may not work with all dates but I have no data to play with and need to go out for wood!

    EDIT - there are ways to always round up, so maybe this
    -int(-DateDiff("d",#01/02/2022#,#06/01/2022#)/28) which equals 6, otherwise the first suggestion rounds down to 5 which I think is not correct.
    I don't understand the purpose of the collections. In the first code example, nothing seems to be done with the collection and I don't see where it's being passed to or called from any other procedure.
    The more we hear silence, the more we begin to think about our value in this universe.
    Paraphrase of Professor Brian Cox.

  5. #5
    CJ_London is offline VIP
    Windows 10 Access 2010 32bit
    Join Date
    Mar 2015
    Posts
    11,397
    Since a year does not equal 52 x 7 or 28 x 13 you are constantly suffering from creep. So your period 1 for 2023 will start on 31st Dec and for 2024 29th Dec and 2025 26th Dec etc. by 2030 your period 1 will be starting around 10th December. Is that what you want? If not, how do you want to handle it?

    And to be clear, your start date for a period is a Saturday - that matters because date functions have a parameter which specifies what day of the week a week starts on which makes calculations easier.

  6. #6
    CJ_London is offline VIP
    Windows 10 Access 2010 32bit
    Join Date
    Mar 2015
    Posts
    11,397
    further to my previous post, one of my clients who works on a 4 week reporting cycle extends the last period so it ends on the the day before when the first period of the following year starts - which in your case would be the day before the first Saturday of the following year. Period 13 for 2022 would end on 31 Dec, for 2023 it would be 6 Jan, etc

  7. #7
    JNL0122 is offline Novice
    Windows 10 Office 365
    Join Date
    Jan 2022
    Posts
    8
    Quote Originally Posted by Welshgasman View Post
    I would use a combo for your 13 periods?
    Perhaps get the data for the current year from a table that holds the periods? What if you want the previous period from last year today?
    Thank you Welshgasman for the reply.

    I am trying not to use a table, primarily because I hope to retire in a few years and might not be around to re-populate it for them. I do want them to be able to get the data for the previous period or pretty much any period that ends less than a year earlier. My idea was to code the option buttons with the 13 periods to provide the start dates and end dates for each period, initially for the 13 past periods, and have the buttons themselves colored amber as an indication they are for the previous year. Then as each period passes in the current year, the button color would change to green to indicate current year and the underlying supplied start and end dates would now be from the current year. So during our current period, (Period 1 of 2022), all of the option buttons would be amber and pressing the amber Period 1 button would supply the Start and End dates of last years Period 1. After we are into Period 2 of this year, there would be 12 amber option buttons and the Period 1 option button would now be green and if pressed provide the dating for the just past Period 1 of the current year, and so on.

    Hope that makes sense.
    Again Thanks
    Joe

  8. #8
    Join Date
    Jan 2017
    Location
    Swansea,South Wales,UK
    Posts
    4,858
    Well to my mind, a table would be the eaisest option for everyone?
    I hope you are going to leave some documentation on how they are meant to use it?
    A small piece of code to add another 5 years worth of data would not be hard? Running that every 5 years is hardly a chore. Or run it now for the next 20 years? Chances are the system will be replaced by then?
    Please use # icon on toolbar when posting code snippets.
    Cross Posting: https://www.excelguru.ca/content.php?184
    Debugging Access: https://www.youtube.com/results?sear...bug+access+vba

  9. #9
    JNL0122 is offline Novice
    Windows 10 Office 365
    Join Date
    Jan 2022
    Posts
    8
    Quote Originally Posted by orange View Post
    Along the lines of Paul's comment, could you have a table with
    period StartDate PeriodEnd

    for as many years as practical (5 back/5 future)

    Hi Orange Thanks very much for the reply and your work on this code!

    I really only need the dating for the previous 13 periods, as well as the dates for each period in the current year relative to the users current date.

    I would like to avoid using a table as I mentioned in my reply to Welshgasman but I did play with your code and if there is no function to be had, I believe your method will be the way to go so Thank you kindly.

    I was thinking in that case, I would be better off not having a hard coded start date, but add a dStartDateSeed field to my already linked Parameters table and maybe having that field updated during year end processing to reflect the start date of the 1st period of the previous year, That way, if management does decide to reset the periods due the creep mentioned by Ajax, there is someplace for them to do that without requiring someone get into the code. Using your code, I am looking at something like this

    [code]
    Sub ReportingPeriodsTest()
    'skeleton to populate a table with
    '28 day reporting periods from 2017 to 2027

    Dim StartDate As Date
    Dim dStartDateSeed As Date
    Dim Periodlen As Integer
    Dim periodEnd As Date
    dStartDateSeed = CDate(DLookup("dStartDateSeed", "Parameters")) ' single record table so no qualifier needed
    StartDate = dStartDateSeed
    Periodlen = 27
    Dim i As Integer
    i = 1
    Do Until StartDate > DateAdd("yyyy", 3, dStartDateSeed)
    ' Do Until StartDate > #12/30/2027#
    periodEnd = DateAdd("d", Periodlen, StartDate)
    Debug.Print i, StartDate, periodEnd 'for testing (could write to a table)
    StartDate = periodEnd + 1
    i = i + 1
    If i > 13 Then i = 1
    Loop
    End Sub
    [code/]

    The downside would be that someone would have to run the code to update the TblReportingPeriods each year.
    Code:
    'Updated the code and included a query:
    
    'Create a table:
    Sub ReportingPeriods()
        On Error GoTo ReportingPeriods_Error
        'skeleton to populate a table with
        '28 day reporting periods from 2021 to 2024
        Dim cSQL As String, Cinsert As String
        'On Error Resume Next
        CurrentDb.Execute "drop table TblReportingPeriods;"
        cSQL = "Create Table TblReportingPeriods (" _
            & "PK AUTOINCREMENT PRIMARY KEY" _
            & ",Period integer " _
            & ",StartDate  Date  " _
            & ",PeriodEnd Date " _
            & ",constraint UX_Start unique(StartDate ) " _
            & ");"
       Cinsert = "INSERT INTO TblReportingPeriods(Period,StartDate,PeriodEnd) VALUES("
    
        Debug.Print cSQL
     
        CurrentDb.Execute cSQL, dbFailOnError
      
        Dim StartDate  As Date
        Dim dStartDateSeed As Date
        Dim Periodlen As Integer
        Dim periodEnd As Date
        dStartDateSeed = CDate(DLookup("dStartDateSeed", "Parameters")) ' single record table so no qualifier needed
        StartDate = dStartDateSeed
        'StartDate = #1/2/2021#
        Periodlen = 27
        Dim i As Integer
        i = 1
        Do Until StartDate > DateAdd("yyyy", 3, dStartDateSeed)
        'Do Until StartDate > #12/24/2030#
            periodEnd = DateAdd("d", Periodlen, StartDate)
            Debug.Print i, StartDate, periodEnd
            'Debug.Print Cinsert & i & ",#" & StartDate & "#,#" & periodEnd & "#)"
            CurrentDb.Execute Cinsert & i & ",#" & StartDate & "#,#" & periodEnd & "#)", dbFailOnError
            StartDate = periodEnd + 1
            i = i + 1
            If i > 13 Then i = 1
        Loop
        
        On Error GoTo 0
    ReportingPeriods_Exit:
        Exit Sub
    
    ReportingPeriods_Error:
    
        MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure ReportingPeriods, line " & Erl & "."
        GoTo ReportingPeriods_Exit
    End Sub
    
    '

    Updated the code and included a query:


    Query:
    PARAMETERs myDateMMDDYYYY date;
    SELECT Period,TblReportingPeriods.StartDate, TblReportingPeriods.PeriodEnd
    FROM TblReportingPeriods
    where startDate <=myDateMMDDYYYY and PeriodEnd>= myDateMMDDYYYY
    Thanks again for the all your work. It's been good to look at this from a different point of view.

    Joe

  10. #10
    JNL0122 is offline Novice
    Windows 10 Office 365
    Join Date
    Jan 2022
    Posts
    8
    Hi Micron Thanks for taking the time to help me.

    Quote Originally Posted by Micron View Post
    maybe take the span from 01/02/2022 to the end date rather than have multiple periods that are the same.
    round(DateDiff("d",#01/02/2022#,#06/18/2022#)/28,0) gives period 6. Rounding may not work with all dates but I have no data to play with and need to go out for wood!

    EDIT - there are ways to always round up, so maybe this
    -int(-DateDiff("d",#01/02/2022#,#06/01/2022#)/28) which equals 6, otherwise the first suggestion rounds down to 5 which I think is not correct.
    I was looking at using this Rounddown function that I found on the web

    Code:
    Public Function RoundDown(pValue, digit) As Double ' Access-Excel tips
        ExpVal = Abs(pValue) * (10 ^ digit) ' Get the integer part of the number
        RoundDown = Sgn(pValue) * Int(ExpVal) / (10 ^ digit)
        
    End Function
    Using it and specifying 2 decimal places yields something I can test on.
    ? rounddown(DateDiff("d",#01/02/2022#,#06/01/2022#)/28,2)
    5.35
    If there is anything at all greater than the Integer part, it must be in the next period. I need two decimals because some dates resulted in too many zeros after the decimal point that access saw them as no different than the integer

    I don't understand the purpose of the collections. In the first code example, nothing seems to be done with the collection and I don't see where it's being passed to or called from any other procedure.
    The function FPrd(PdNum) is using the collection to return the Start and End dates of the Period number passed to it. I used a variant for the PDNum, because I had the idea I could also pass the Strings "Current" and "Previous" to it and have the code inside to properly assign the Period Number that way. It does work as intended excepting it numbers 26 periods a 1 to 26 with Period 1 of the current year being #14
    I have been calling it from the both sub routine called TestDates() and the function findperiod,
    The real problem is that it is limited to 26 periods as written and responds with a period 0 (Zero) if the date passed to it is outside of those 26 periods, so would require updating the code regularly to adjust for the rolling nature of the reporting periods.

    Again Thank you for replying
    You all are awesome

    Joe

  11. #11
    JNL0122 is offline Novice
    Windows 10 Office 365
    Join Date
    Jan 2022
    Posts
    8
    Hi again Welshgasman

    You are of course right.

    It would be the easiest option, and I am leaning that way right now. I could run it and set up the table for 5 or even 20 years. Its is very likely the system would be replaced by then.
    The issue identified by Ajax above is of concern though. I have asked, and no one at my location has any idea when corporate went to these 28 day reporting periods or if there is a plan to reset them at some point. I just know I have been in my current position for 12 years and this is the 1st time that the beginning of the period coincided exactly with the 1st day of the year. I think Ajax's point can best be addressed with using the parameter table entry.
    Thanks again
    Joe

  12. #12
    JNL0122 is offline Novice
    Windows 10 Office 365
    Join Date
    Jan 2022
    Posts
    8
    Hi again Welshgasman

    You are of course right.

    It would be the easiest option, and I am leaning that way right now. I could run it and set up the table for 5 or even 20 years. Its is very likely the system would be replaced by then.
    The issue identified by Ajax above is of concern though. I have asked, and no one at my location has any idea when corporate went to these 28 day reporting periods or if there is a plan to reset them at some point. I just know I have been in my current position for 12 years and this is the 1st time that the beginning of the period coincided exactly with the 1st day of the year. I think Ajax's point can best be addressed with using the parameter table entry.

    Thanks again
    Joe

  13. #13
    JNL0122 is offline Novice
    Windows 10 Office 365
    Join Date
    Jan 2022
    Posts
    8
    Hi Ajax!
    Thank you for your thoughtful comments


    Quote Originally Posted by Ajax View Post
    Since a year does not equal 52 x 7 or 28 x 13 you are constantly suffering from creep. So your period 1 for 2023 will start on 31st Dec and for 2024 29th Dec and 2025 26th Dec etc. by 2030 your period 1 will be starting around 10th December. Is that what you want? If not, how do you want to handle it?

    And to be clear, your start date for a period is a Saturday - that matters because date functions have a parameter which specifies what day of the week a week starts on which makes calculations easier.
    It is.
    For our purposes it does not matter what day the period ends, just that it is exactly the same length in days as the periods before it, and those that come after. I can't say for sure that they will never reset them, but it has not happened in the 12 years I have been in my current position. Your comments though got me thinking that I should allow for them deciding to adjust for the creep at some point. I am now leaning towards adding an entry into the databases parameter table to have that flexibility. Thank you.

    Thanks again

    Joe

  14. #14
    CJ_London is offline VIP
    Windows 10 Access 2010 32bit
    Join Date
    Mar 2015
    Posts
    11,397
    if you have a history of periods going back 6 or more years you can see how they have been treated in the past so be guided by that.

    My figures were slightly exaggerated but basically you will lose a day a year, 2 in a leap year so in 5 or 6 years (depending how many leap years) you will have lost a week. As I said in my other post, a client on mine 'resets' the start of the period to the first (Monday in their case) of January. The last period of the previous year is then adjusted. The adjustment is only 1 or 2 days (depending on leap year) - so 29 or 30 days depending and for 3 years out of 4 they are all 29 days so year on year comparisons were pretty consistent. And don't forget that period covers Xmas and New Year - which for them was a quiet period so prior period comparisons were consistent.

    Or perhaps every 20 years or so you have a 14 periods in a year.

    Or perhaps you don't need to reference periods and years as periods 1,2,3 of 2020, 2021 etc. just let the period number accumulate 12,13,14,...20,21... etc and they start in whatever year they happen to be.

  15. #15
    Micron is offline Virtually Inert Person
    Windows 10 Access 2016
    Join Date
    Jun 2014
    Location
    Ontario, Canada
    Posts
    12,737
    I'm not following the notion of rounding down. If the result is 5.1, you have completed 5 and are in the 6th period, so round up? However, the idea I posted results in exactly 5 for 05/22/2022 so it's certainly not perfect. No matter, it seems that you have a way forward now.
    The more we hear silence, the more we begin to think about our value in this universe.
    Paraphrase of Professor Brian Cox.

Page 1 of 2 12 LastLast
Please reply to this thread with any new information or opinions.

Similar Threads

  1. Replies: 5
    Last Post: 11-06-2020, 08:21 PM
  2. Simple SETVALUE function
    By fishhead in forum Access
    Replies: 2
    Last Post: 07-21-2020, 05:53 PM
  3. Simple passing into function question
    By Ruegen in forum Programming
    Replies: 3
    Last Post: 07-24-2014, 11:23 PM
  4. Replies: 4
    Last Post: 05-25-2014, 02:01 AM
  5. Need Help with Simple VB Function
    By nrage21 in forum Programming
    Replies: 2
    Last Post: 09-21-2010, 09:14 AM

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  
Other Forums: Microsoft Office Forums