Problem with Email from Access

[SeniorCitizen]

I am attempting to send an email from an access database via Outlook with a word doc as the body of the email. I have copied the following from another post and changed only the path to my document.\ for a place to start but cant get past the first Dim statement. I get an error 'User defined type undefined'. I also get the same error with other attempts when using the Dim oMail or any other o object.

I have checked the following libraries:Visual Basic for apps, MS Access 16.0 Obj Lib, MS Word 16.o Obj Lib, MS Office 16.0 Obj Lib and MS Outlook 16.0 Obj Lib.

I'm obviously missing something. Any thoughts?

Private Sub BtnSend_Click()
Dim wd As Word.Application
Dim doc As Word.Document
Dim itm As Outlook.MailItem
Dim ID As String
Dim blnWeOpenedWord As Boolean
On Error Resume Next

Set wd = GetObject(, "Word.Application")
If wd Is Nothing Then
Set wd = CreateObject("Word.Application")
blnWeOpenedWord = True


End If
Set doc = wd.Documents.Open _
(FileName:="E:\Paradise\Paradise Cancellation Policy.doc", ReadOnly:=True)
Set itm = doc.MailEnvelope.Item
With itm
.To = "someone@somewhere.com"
.Subject = "My Subject"
.Send
End With
doc.Close wdDoNotSaveChanges
If blnWeOpenedWord Then
wd.Quit
End If

Set doc = Nothing
Set itm = Nothing
Set wd = Nothing
End Sub

[Gicu]

Can you please try this version that uses late binding:

Dim wd As Object 'Word.Application
Dim doc As Object 'Word.Document
Dim itm As Object 'Outlook.MailItem
Dim ID As String
Dim blnWeOpenedWord As Boolean
On Error Resume Next


'Set wd = GetObject(, "Word.Application")
'If wd Is Nothing Then
Set wd = CreateObject("Word.Application")
blnWeOpenedWord = True
'End If
Set doc = wd.Documents.Open _
(FileName:="E:\Paradise\Paradise Cancellation Policy.doc", ReadOnly:=True)
Set itm = doc.MailEnvelope.Item
With itm
.To = "someone@somewhere.com"
.Subject = "My Subject"
.Send
End With
doc.Close 0 'wdDoNotSaveChanges
If blnWeOpenedWord Then
wd.Quit
End If


Set doc = Nothing
Set itm = Nothing
Set wd = Nothing

Cheers,

[June7]

I tested the original code. Compiles and runs without error and email is sent.

Please post code between CODE tags to retain indentation and readability.

[SeniorCitizen]

Thanks Gicu, I made the suggested changes and it seems to be getting the doc and emailing it. I dont fully understand to early/late binding but I will accept it.

Great help
Thanks

[SeniorCitizen]

Is there any problem with the recipient getting it when the are not using Outlook?

[June7]

Should not matter what email tool recipient uses. Just as it doesn't when you manually create email directly in Outlook.

[Gicu]

Glad to hear it works for you. Late binding does not need you to set references to other libraries and it is preferred when you have users using a mix of MS Office versions as early binding is not backwards compatible.

Cheers,