Page 1 of 2 12 LastLast
Results 1 to 15 of 20
  1. #1
    Blings's Avatar
    Blings is offline Competent Performer
    Windows 10 Office 365
    Join Date
    May 2020
    Location
    London, UK
    Posts
    125

    Should I look at SQL Server for my backend storage instead of my current Access tables?

    I am busy creating a new business process of a Sales Order system that creates a Sales Order by filling in the Sales Order form which defines a customers` sale, subsequently via their intend to purchase from their Purchase Order.



    Instead of leaving the purchase order attached to an email on email I would like to download their purchase order and attach it to the sales order we will create on our database. Now, my question is, can I have an attachment data field that can list many attachments added to that particular sales order ID and should I move away from Access tables as I know Access database max size is 2 GB less system objects.

    Would now be a good time to upgrade from Access tables to SQL Server or Azure SQL?

    Approximately 420 new records will be made monthly each having a PDF attachment (190 KB average), that puts the storage of purchase orders at 80 MB a month give or take.

  2. #2
    pbaldy's Avatar
    pbaldy is offline Who is John Galt?
    Windows XP Access 2007
    Join Date
    Feb 2010
    Location
    Nevada, USA
    Posts
    22,518
    Many of us would avoid the attachment data type entirely, no matter the back end. We'd store the object (PDF, image, etc) in a central location and store the path to it in a text field in the database. I have a driver's app where I store things like pictures of their license, medical certificates, etc that way.
    Paul (wino moderator)
    MS Access MVP 2007-2019
    www.BaldyWeb.com

  3. #3
    Blings's Avatar
    Blings is offline Competent Performer
    Windows 10 Office 365
    Join Date
    May 2020
    Location
    London, UK
    Posts
    125
    Okay, thanks. With the help of @mike60smart, we developed a similar approach for my Human Resources database.

    Code:
    Private Sub cmd_LocateFile_Click()    On Error GoTo Error_Handler
        Dim sFile                 As String
        Dim sFolder               As String
    
    
        sFile = FSBrowse("", msoFileDialogFilePicker, "All Files (*.*),*.*")
        If sFile <> "" Then
            sFolder = Application.CodeProject.path & "\" & sAttachmentFolderName & "\"
            'Ensure the Attachment folder exists
            If FolderExist(sFolder) = False Then MkDir (sFolder)
            'Copy the file to the Attachment folder
            If CopyFile(sFile, sFolder & GetFileName(sFile)) = True Then
                'Add this new path to our db
                Me.FullFileName = sFolder & GetFileName(sFile)
                Me.Description = sFile
            Else
                'Probably should report something here about the File Copy failing
            End If
        End If
    
    
    Error_Handler_Exit:
        On Error Resume Next
        Exit Sub
    
    
    Error_Handler:
        MsgBox "The following error has occured" & vbCrLf & vbCrLf & _
               "Error Number: " & Err.Number & vbCrLf & _
               "Error Source: " & sModName & "\cmd_LocateFile_Click" & vbCrLf & _
               "Error Description: " & Err.Description & _
               Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
               , vbOKOnly + vbCritical, "An Error has Occured!"
        Resume Error_Handler_Exit
    End Sub
    I am trying to change the "Me.Description = sFile" to only update the description as the name of the file as uploaded by the user. Can you suggest alternative code that could do that, please? This way I can store the file out of the database and in an 'Attachments' folder on the server, however, the current code creates an 'Attachements' folder on the users` local computer and not the network which is what I require so that others can grab the file if required.

  4. #4
    Minty is online now VIP
    Windows 10 Office 365
    Join Date
    Sep 2017
    Location
    UK - Wiltshire
    Posts
    3,001
    I would store your top level UNC path as a field in a setting table.

    Code:
    Field - TopLevelStorePath
    Data - "\\MyServer\DatabaseStuff\ClientData\"
    Then in your code you load this as a Public Variable at start up somewhere

    Code:
    Global glstrStoreagePath as String
    glstrStoreagePath  = DLookup("TopLevelStorePath","MySettingsTable")
    Now when you need to store something the file path is simply something like
    Code:
    glstrStoreagePath & Me.ClientCode & "\MySaveFileName.pdf"
    If you ever move your server file around all you need to do is change one bit of data in one field in your settings table.

    Notice I used a UNC path, NOT a mapped drive. Mapped drives can be very unreliable, unless your IT dept has them fully locked down.
    DLookup Syntax and others http://access.mvps.org/access/general/gen0018.htm
    Please use the star below the post to say thanks if we have helped !
    ↓↓ It's down here ↓↓

  5. #5
    pbaldy's Avatar
    pbaldy is offline Who is John Galt?
    Windows XP Access 2007
    Join Date
    Feb 2010
    Location
    Nevada, USA
    Posts
    22,518
    Quote Originally Posted by Blings View Post
    I am trying to change the "Me.Description = sFile" to only update the description as the name of the file as uploaded by the user. Can you suggest alternative code that could do that, please? This way I can store the file out of the database and in an 'Attachments' folder on the server, however, the current code creates an 'Attachements' folder on the users` local computer and not the network which is what I require so that others can grab the file if required.
    If you're saying that Application.CodeProject.path returns a path on the user's computer, replace that with a fixed path either in code or stored in a table as Minty has described. If you just want the file name, perhaps:

    Me.Description = GetFileName(sFile)
    Paul (wino moderator)
    MS Access MVP 2007-2019
    www.BaldyWeb.com

  6. #6
    isladogs's Avatar
    isladogs is offline MVP / VIP
    Windows 10 Access 2010 32bit
    Join Date
    Jan 2014
    Location
    Somerset, UK
    Posts
    5,954
    Coming back to the question about upsizing to SQL Server, it is likely to take several years before you could approach the 2GB limit, especially if you bin the use of attachment fields.
    Archiving old data periodically may mean that you can postpone that day even longer.

    Apart from the file size issue, the main reasons for moving to SQL Server are for improvements to both stability and security.
    It is highly unlikely that performance will improve and it may actually deteriorate initially.
    In order to get improved performance you will need to move as much of the processing to the server as possible..
    Colin, Access MVP, Website, email
    The more I learn, the more I know I don't know. When I don't know, I keep quiet!
    If I don't know that I don't know, I don't know whether to answer

  7. #7
    Blings's Avatar
    Blings is offline Competent Performer
    Windows 10 Office 365
    Join Date
    May 2020
    Location
    London, UK
    Posts
    125
    Quote Originally Posted by pbaldy View Post
    Me.Description = GetFileName(sFile)
    That worked perfectly. Thank you @pbadly.

    I'm going to work through @Minty's suggestions then come back to this thread.

  8. #8
    Blings's Avatar
    Blings is offline Competent Performer
    Windows 10 Office 365
    Join Date
    May 2020
    Location
    London, UK
    Posts
    125
    Currently a user needs to upload a file by picking the orange button "..." as seen below. Is it possible to allow a drag and drop area which will fulfil the same functionality as the orange button too?
    Attached Thumbnails Attached Thumbnails HR DB Documents Upload.jpg  

  9. #9
    pbaldy's Avatar
    pbaldy is offline Who is John Galt?
    Windows XP Access 2007
    Join Date
    Feb 2010
    Location
    Nevada, USA
    Posts
    22,518
    Quote Originally Posted by Blings View Post
    That worked perfectly. Thank you @pbadly.
    Happy to help!

    To your followup question, not that I'm aware of. Wouldn't be the first thing I wasn't aware of though.
    Paul (wino moderator)
    MS Access MVP 2007-2019
    www.BaldyWeb.com

  10. #10
    Minty is online now VIP
    Windows 10 Office 365
    Join Date
    Sep 2017
    Location
    UK - Wiltshire
    Posts
    3,001
    I think I have seen a demo of Drag and drop in Access somewhere on the Interwebs.
    I'll have a poke around and see if I can steer you towards it. I suspect it wasn't very easy to code...
    DLookup Syntax and others http://access.mvps.org/access/general/gen0018.htm
    Please use the star below the post to say thanks if we have helped !
    ↓↓ It's down here ↓↓

  11. #11
    Blings's Avatar
    Blings is offline Competent Performer
    Windows 10 Office 365
    Join Date
    May 2020
    Location
    London, UK
    Posts
    125
    @Minty,

    I want to follow your method of storing the file data and creating a master path, please.

    Tables:

    Click image for larger version. 

Name:	t_Attachments_Server.JPG 
Views:	31 
Size:	17.3 KB 
ID:	45770
    Click image for larger version. 

Name:	t_Attachments_Server_Settings.JPG 
Views:	29 
Size:	18.0 KB 
ID:	45771

    On click event button for the file picker.

    Code:
    Private Sub cmd_LocateFile_Click()    On Error GoTo Error_Handler
        Dim sFile                 As String
        Dim sFolder               As String
    
    
        sFile = FSBrowse("", msoFileDialogFilePicker, "All Files (*.*),*.*")
        If sFile <> "" Then
            sFolder = Application.CodeProject.path & "\" & sAttachmentFolderName & "\"
            'Ensure the Attachment folder exists
            If FolderExist(sFolder) = False Then MkDir (sFolder)
            'Copy the file to the Attachment folder
            If CopyFile(sFile, sFolder & GetFileName(sFile)) = True Then
                'Add this new path to our db
                Me.FullFileName = sFolder & GetFileName(sFile)
                Me.Description = GetFileName(sFile)
            Else
                'Probably should report something here about the File Copy failing
            End If
        End If
    
    
    Error_Handler_Exit:
        On Error Resume Next
        Exit Sub
    
    
    Error_Handler:
        MsgBox "The following error has occured" & vbCrLf & vbCrLf & _
               "Error Number: " & Err.Number & vbCrLf & _
               "Error Source: " & sModName & "\cmd_LocateFile_Click" & vbCrLf & _
               "Error Description: " & Err.Description & _
               Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
               , vbOKOnly + vbCritical, "An Error has Occured!"
        Resume Error_Handler_Exit
    End Sub
    On click event for delete button.

    Code:
    'Delete the current attachment/record and the attachment file itselfPrivate Sub cmd_RecDel_Click()
        On Error GoTo Error_Handler
        Dim sFile                 As String
        
        sFile = Me.FullFileName
        'Delete the database record
        DoCmd.DoMenuItem acFormBar, acEditMenu, 8, , acMenuVer70
        DoCmd.DoMenuItem acFormBar, acEditMenu, 6, , acMenuVer70
        'If we're here the record was deleted, so let delete the actual file from the server
        Kill sFile
    
    
    Error_Handler_Exit:
        On Error Resume Next
        Exit Sub
    
    
    Error_Handler:
        If Err.Number <> 2501 Then
            MsgBox "The following error has occured" & vbCrLf & vbCrLf & _
                   "Error Number: " & Err.Number & vbCrLf & _
                   "Error Source: " & sModName & "\cmd_RecDel_Click" & vbCrLf & _
                   "Error Description: " & Err.Description & _
                   Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
                   , vbOKOnly + vbCritical, "An Error has Occured!"
        End If
        Resume Error_Handler_Exit
    End Sub
    On click event for open attachment button.

    Code:
    'Open the attachmentPrivate Sub cmd_ViewFile_Click()
        On Error GoTo Error_Handler
    
    
        Call ExecuteFile(Me.FullFileName, "Open")
    
    
    Error_Handler_Exit:
        On Error Resume Next
        Exit Sub
    
    
    Error_Handler:
        MsgBox "The following error has occured" & vbCrLf & vbCrLf & _
               "Error Number: " & Err.Number & vbCrLf & _
               "Error Source: " & sModName & "\cmd_ViewFile_Click" & vbCrLf & _
               "Error Description: " & Err.Description & _
               Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
               , vbOKOnly + vbCritical, "An Error has Occured!"
        Resume Error_Handler_Exit
    End Sub
    Module 1 of 2.

    Code:
    '***************************************************************************************' Module    : mod_ExternalFiles
    ' Author    : CARDA Consultants Inc.
    ' Website   : http://www.cardaconsultants.com
    ' Copyright : Please note that U.O.S. all the content herein considered to be
    '             intellectual property (copyrighted material).
    '             It may not be copied, reused or modified in any way without prior
    '             authorization from its author(s).
    '***************************************************************************************
    
    
    Option Compare Database
    Option Explicit
    
    
    Private Const sModName = "mod_ExternalFiles" 'Application.VBE.ActiveCodePane.CodeModule
    
    
    'Source: http://www.pacificdb.com.au/MVP/Code/ExeFile.htm
    Public Const SW_HIDE = 0
    Public Const SW_MINIMIZE = 6
    Public Const SW_RESTORE = 9
    Public Const SW_SHOW = 5
    Public Const SW_SHOWMAXIMIZED = 3
    Public Const SW_SHOWMINIMIZED = 2
    Public Const SW_SHOWMINNOACTIVE = 7
    Public Const SW_SHOWNA = 8
    Public Const SW_SHOWNOACTIVATE = 4
    Public Const SW_SHOWNORMAL = 1
    
    
    Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" _
                                         (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, _
                                          ByVal lpParameters As String, ByVal lpDirectory As String, _
                                          ByVal nShowCmd As Long) As Long
    
    
    
    
    Public Sub ExecuteFile(sFileName As String, sAction As String)
        Dim vReturn               As Long
        'sAction can be either "Open" or "Print".
    
    
        If ShellExecute(Access.hWndAccessApp, sAction, sFileName, vbNullString, "", SW_SHOWNORMAL) < 33 Then
            DoCmd.Beep
            MsgBox "File not found."
        End If
    End Sub
    
    
    
    
    'FSBrowse (File System Browse) allows the operator to browse for a file/folder.
    '  strStart specifies where the process should start the browser.
    '  lngType specifies the MsoFileDialogType to use.
    '           msoFileDialogOpen           1   Open dialog box.
    '           msoFileDialogSaveAs         2   Save As dialog box.
    '           msoFileDialogFilePicker     3   File picker dialog box.
    '           msoFileDialogFolderPicker   4   Folder picker dialog box.
    '  strPattern specifies which FileType(s) should be included.
    '
    '    Dim sFile                 As String
    '    sFile = FSBrowse("", msoFileDialogFilePicker, "MS Excel,*.XLSX; *.XLSM; *.XLS")
    '    If sFile <> "" Then Me.txt_FinData_Src = sFile
    '***** Requires a Reference to the 'Microsoft Office XX.X Object Library *****
    Public Function FSBrowse(Optional strStart As String = "", _
                             Optional lngType As MsoFileDialogType = _
                             msoFileDialogFolderPicker, _
                             Optional strPattern As String = "All Files,*.*" _
                             ) As String
        Dim varEntry              As Variant
    
    
        FSBrowse = ""
        With Application.FileDialog(dialogType:=lngType)
            'Set the title to match the type used from the list
            .title = "Browse for "
            Select Case lngType
                Case msoFileDialogOpen
                    .title = .title & "File to open"
                Case msoFileDialogSaveAs
                    .title = .title & "File to SaveAs"
                Case msoFileDialogFilePicker
                    .title = .title & "File"
                Case msoFileDialogFolderPicker
                    .title = .title & "Folder"
            End Select
            If lngType <> msoFileDialogFolderPicker Then
                'Reset then add filter patterns separated by tildes (~) where
                '  multiple extensions are separated by semi-colons (;) and the
                '  description is separated from them by a comma (,).
                '  Example strPattern :
                '  "MS Access,*.ACCDB; *.MDB~MS Excel,*.XLSX; *.XLSM; *.XLS"
                Call .Filters.Clear
                For Each varEntry In Split(strPattern, "~")
                    Call .Filters.Add(Description:=Split(varEntry, ",")(0), _
                                      Extensions:=Split(varEntry, ",")(1))
                Next varEntry
            End If
            'Set some default settings
            .InitialFileName = strStart
            .AllowMultiSelect = False
            .InitialView = msoFileDialogViewDetails
            'Only return a value from the FileDialog if not cancelled.
            If .Show Then FSBrowse = .SelectedItems(1)
        End With
    End Function
    
    
    '---------------------------------------------------------------------------------------
    ' Procedure : FolderExist
    ' DateTime  : 2009-Oct-02 13:51
    ' Author    : CARDA Consultants Inc.
    ' Website   : http://www.cardaconsultants.com
    ' Purpose   : Test for the existance of a Folder/Directory
    ' Copyright : The following may be altered and reused as you wish so long as the
    '             copyright notice is left unchanged (including Author, Website and
    '             Copyright).  It may not be sold/resold or reposted on other sites (links
    '             back to this site are allowed).
    '
    ' Input Variables:
    ' ~~~~~~~~~~~~~~~~
    ' sFolder - Full path of the folder to be tested for
    '---------------------------------------------------------------------------------------
    Function FolderExist(sFolder As String) As Boolean
        On Error GoTo Error_Handler
    
    
        If sFolder = vbNullString Then GoTo Error_Handler_Exit
        If Dir(sFolder, vbDirectory) <> vbNullString Then
            FolderExist = True
        End If
    
    
    Error_Handler_Exit:
        On Error Resume Next
        Exit Function
    
    
    Error_Handler:
        If Err.Number <> 52 Then
            MsgBox "The following error has occured" & vbCrLf & vbCrLf & _
                   "Error Number: " & Err.Number & vbCrLf & _
                   "Error Source: " & sModName & "\FolderExist" & vbCrLf & _
                   "Error Description: " & Err.Description & _
                   Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
                   , vbOKOnly + vbCritical, "An Error has Occured!"
        End If
        Resume Error_Handler_Exit
    End Function
    
    
    '---------------------------------------------------------------------------------------
    ' Procedure : CopyFile
    ' Author    : CARDA Consultants Inc.
    ' Website   : http://www.cardaconsultants.com
    ' Purpose   : Copy a file
    '             Overwrites existing copy without prompting
    '             Cannot copy locked files (currently in use)
    ' Copyright : The following may be altered and reused as you wish so long as the
    '             copyright notice is left unchanged (including Author, Website and
    '             Copyright).  It may not be sold/resold or reposted on other sites (links
    '             back to this site are allowed).
    '
    ' Input Variables:
    ' ~~~~~~~~~~~~~~~~
    ' strSource - Path/Name of the file to be copied
    ' strDest - Path/Name for copying the file to
    '
    ' Revision History:
    ' Rev       Date(yyyy/mm/dd)        Description
    ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ' 1         2007-Apr-01             Initial Release
    '---------------------------------------------------------------------------------------
    Function CopyFile(strSource As String, strDest As String) As Boolean
        On Error GoTo CopyFile_Error
    
    
        FileCopy strSource, strDest
        CopyFile = True
        Exit Function
    
    
    CopyFile_Error:
        If Err.Number = 0 Then
        ElseIf Err.Number = 70 Then
            MsgBox "The file is currently in use and therfore is locked and cannot be copied at this" & _
                   " time.  Please ensure that no one is using the file and try again.", vbOKOnly, _
                   "File Currently in Use"
        ElseIf Err.Number = 53 Then
            MsgBox "The Source File '" & strSource & "' could not be found.  Please validate the" & _
                   " location and name of the specifed Source File and try again", vbOKOnly, _
                   "File Currently in Use"
        Else
            MsgBox "The following error has occured" & vbCrLf & vbCrLf & _
                   "Error Number: " & Err.Number & vbCrLf & _
                   "Error Source: " & sModName & "\CopyFile" & vbCrLf & _
                   "Error Description: " & Err.Description & _
                   Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
                   , vbOKOnly + vbCritical, "An Error has Occured!"
        End If
        Exit Function
    End Function
    
    
    '---------------------------------------------------------------------------------------
    ' Procedure : GetFileName
    ' Author    : CARDA Consultants Inc.
    ' Website   : http://www.cardaconsultants.com
    ' Purpose   : Return the filename from a path\filename input
    ' Copyright : The following may be altered and reused as you wish so long as the
    '             copyright notice is left unchanged (including Author, Website and
    '             Copyright).  It may not be sold/resold or reposted on other sites (links
    '             back to this site are allowed).
    '
    ' Input Variables:
    ' ~~~~~~~~~~~~~~~~
    ' sFile - string of a path and filename (ie: "c:\temp\test.xls")
    '
    ' Revision History:
    ' Rev       Date(yyyy/mm/dd)        Description
    ' **************************************************************************************
    ' 1         2008-Feb-06                 Initial Release
    '---------------------------------------------------------------------------------------
    Function GetFileName(sFile As String)
        On Error GoTo Err_Handler
    
    
        GetFileName = Right(sFile, Len(sFile) - InStrRev(sFile, "\"))
    
    
    Exit_Err_Handler:
        Exit Function
    
    
    Err_Handler:
        MsgBox "The following error has occured" & vbCrLf & vbCrLf & _
               "Error Number: " & Err.Number & vbCrLf & _
               "Error Source: " & sModName & "\GetFileName" & vbCrLf & _
               "Error Description: " & Err.Description & _
               Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
               , vbOKOnly + vbCritical, "An Error has Occured!"
        GoTo Exit_Err_Handler
    End Function
    Module 2 of 2.

    Code:
    '***************************************************************************************' Module    : mod_DB_Variables
    ' Author    : CARDA Consultants Inc.
    ' Website   : http://www.cardaconsultants.com
    ' Copyright : Please note that U.O.S. all the content herein considered to be
    '             intellectual property (copyrighted material).
    '             It may not be copied, reused or modified in any way without prior
    '             authorization from its author(s).
    '***************************************************************************************
    
    
    Option Compare Database
    Option Explicit
    
    
    Private Const sModName = "mod_DB_Variables"
    
    
    
    
    Public Const sAttachmentFolderName = "Attachments"

  12. #12
    Minty is online now VIP
    Windows 10 Office 365
    Join Date
    Sep 2017
    Location
    UK - Wiltshire
    Posts
    3,001
    Without being rude, or deciphering a lot of code, what is your question?

    Is something not working?
    DLookup Syntax and others http://access.mvps.org/access/general/gen0018.htm
    Please use the star below the post to say thanks if we have helped !
    ↓↓ It's down here ↓↓

  13. #13
    Blings's Avatar
    Blings is offline Competent Performer
    Windows 10 Office 365
    Join Date
    May 2020
    Location
    London, UK
    Posts
    125
    Quote Originally Posted by Minty View Post
    Without being rude, or deciphering a lot of code, what is your question?

    Is something not working?
    Haha, sorry, I should have mentioned. Where should the public variable be placed and can you see where I can update the file path?

    Code:
    Global glstrStoreagePath as String
    glstrStoreagePath  = DLookup("TopLevelStorePath","MySettingsTable")
    Thank you for looking into this.

  14. #14
    Minty is online now VIP
    Windows 10 Office 365
    Join Date
    Sep 2017
    Location
    UK - Wiltshire
    Posts
    3,001
    You will need to declare the variable at the top of a code module (Not a forms code module) , here is the start of a module I use called modBasFunctions
    It stores the commonly used functions I use in many databases.
    Code:
    Option Compare Database
    Option Explicit
    
    Global glb_EmpID            As Integer
    Global glb_UserAccLvl       As Integer
    Global glbServerSavePath    As String
    
    
    Public Function TrailingSlash(varIn As Variant) As String
        If Len(varIn) > 0& Then
            If Right(varIn, 1&) = "\" Then
                TrailingSlash = varIn
            Else
                TrailingSlash = varIn & "\"
            End If
        End If
    End Function
    
    Function FileExists(ByVal strFile As String, Optional bFindFolders As Boolean) As Boolean
    'Purpose:   Return True if the file exists, even if it is hidden.
    'Arguments: strFile: File name to look for. Current directory searched if no path included.
    '           bFindFolders. If strFile is a folder, FileExists() returns False unless this argument is True.
    'Note:      Does not look inside subdirectories for the file.
    'Author:    Allen Browne. http://allenbrowne.com June, 2006.
        Dim lngAttributes    As Long
    .....
    You then need to make sure it is set somewhere in your Access database start up process.
    Again I tend to chuck a Public sub into another module modStartUp that sets up these type of things.
    It gets called in the Login or Main Menu form load events.
    DLookup Syntax and others http://access.mvps.org/access/general/gen0018.htm
    Please use the star below the post to say thanks if we have helped !
    ↓↓ It's down here ↓↓

  15. #15
    Blings's Avatar
    Blings is offline Competent Performer
    Windows 10 Office 365
    Join Date
    May 2020
    Location
    London, UK
    Posts
    125
    Not quite sure where to start on that. Thanks for your help.

Page 1 of 2 12 LastLast
Please reply to this thread with any new information or opinions.

Similar Threads

  1. Replies: 3
    Last Post: 08-06-2021, 06:27 AM
  2. Re-Link to backend data on network attached storage
    By GraeagleBill in forum Access
    Replies: 6
    Last Post: 06-11-2018, 05:10 PM
  3. Parsing HTML Tables for Storage in Access
    By Stopwatch in forum Import/Export Data
    Replies: 8
    Last Post: 09-22-2014, 03:36 PM
  4. Replies: 4
    Last Post: 09-05-2013, 08:02 AM
  5. Replies: 2
    Last Post: 03-21-2011, 12:55 PM

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  
Other Forums: Microsoft Office Forums