Error when exporting report to Word

[templeowls]

Crosspost from here for more exposure. I'm using the following code to export a report to Microsoft Word:

Private Sub cmd_exportformPDF_Click()    Dim reportName As String
    Dim criteria As String
    Dim strfolder As String
    Dim strfilename As String
    
    reportName = "CompletedForm"
    criteria = "[ComplaintNumber]= " & [Forms]![frm2021Details]![ComplaintNumber]
    strfolder = "F:\Documents"
    strfilename = Me.CustomerLastName & ", " & Me.CustomerFirstName & " " & Format(Me.DateOpened, "m.d.yyyy") & ".pdf"
    
    DoCmd.OpenReport reportName, acViewPreview, criteria, acHidden
    DoCmd.OutputTo acOutputReport, reportName, acFormatRTF, strfolder & strfilename
    DoCmd.Close acReport, reportName, acSaveNo
 End Sub

It exports it fine but when trying to open the file, Word says "it found unreadable content" and asks if I want to recover it. I have no images in the report so I'm unsure of the error. I wanted to see if anyone has any experience with this before I abandon and move to bookmarking.

Thanks!

[ranman256]

it seems to do that even tho NOTHING is wrong. It may be a Word warning due to the RTF format.

[Gicu]

You choose acFormatRTF in the Docmd.OutputTo line and yet you force a PDF extension in strfilename. What happens if you replace ".pdf" with ".rtf"?

Cheers,

[templeowls]

My mistake...it was right in my database but wrong here. It's ".docx". That might be my issue. I'll change it to .rtf and report back

[ssanfu]

I see a couple of issues:

Private Sub cmd_exportformPDF_Click()
    Dim reportName As String
    Dim criteria As String
    Dim strfolder As String
    Dim strfilename As String
    
    reportName = "CompletedForm"
    criteria = "[ComplaintNumber]= " & [Forms]![frm2021Details]![ComplaintNumber]
    strfolder = "F:\Documents"    '<<-- missing backslash
    strfilename = Me.CustomerLastName & ", " & Me.CustomerFirstName & " " & Format(Me.DateOpened, "m.d.yyyy") & ".pdf"  '<<-- Not a good idea having a comma in the file name. Also shouldn't have multiple periods in file name
    
    DoCmd.OpenReport reportName, acViewPreview, criteria, acHidden
    DoCmd.OutputTo acOutputReport, reportName, acFormatRTF, strfolder & strfilename   ' <<--  it looks like you are using the report unfiltered by having "reportName" in the objectname parameter
    DoCmd.Close acReport, reportName, acSaveNo
 End Sub

Consider:

Private Sub cmd_exportformPDF_Click()
    Dim reportName As String
    Dim criteria As String
    Dim strfolder As String
    Dim strfilename As String
    
    reportName = "CompletedForm"
    criteria = "[ComplaintNumber]= " & [Forms]![frm2021Details]![ComplaintNumber]
    strfolder = "F:\Documents\"     '<<-- added backslash
    strfilename = strfolder  & Me.CustomerLastName & "_" & Me.CustomerFirstName & "_" & Format(Me.DateOpened, "m_d_yyyy") & ".rtf"
    
    Debug.Print strfilename 

    DoCmd.OpenReport reportName, acViewPreview, criteria, acHidden
    DoCmd.OutputTo acOutputReport, , acFormatRTF, strfilename  ' <<-- Notice no  objectname (see below)
    DoCmd.Close acReport, reportName      ' , acSaveNo means save changes to DESIGN changes - it is not needed when you close the report
 End Sub

[templeowls]

Hi Steve. This did the trick but the word document itself is a mess. Retained none of the formatting really so I think bookmarking is the path I need to go (kinda expected that). I really appreciate the help though

[Gicu]

An alternative to bookmarking is using Word automation with mail-merge, been using that for years with great success. There are few tricks to do it right (don't use an Access table or query as the mail merge source but rather export it to a csv file and use that so the Word document doesn't lock\interact with the db). Have a look at Albert's (super easy)mail merge code, should get you on the right track:
http://www.kallal.ca/msaccess/msaccess.html
Cheers,