Displaying Folder Names Inputbox

[DMT Dave]

Hi Guy's how can i display folder names from the below code please ?



So inputbox is something like

InputBox("Select Folder From Directory " & Me.cboCustomerSource & vbnewline & vbnewline & _
Chr(149) "1 " & Chr(149) = & " Folder Name 1" & vbNewLine & _
Chr(149) "2 " & Chr(149) = & " Folder Name 2" & vbNewLine & _
Chr(149) "3 " & Chr(149) = & " Folder Name 3" & vbNewLine & _
Chr(149) "4 " & Chr(149) = & " Folder Name 4","SELECT FOLDE")

If Me.cboCustomerSource <> "" ThenIf Me.cboCustomer = Me.cboCustomerSource Then
Dim SrcPath As String, srcFile As String, strFld As String, myFld As String
SrcPath = "T:\" & Me.cboCustomerSource & "\" ' THERE MAY 4 folders in SrcPath
myFld = InputBox("Enter The Folder To Populate ?" & vbNewLine & vbNewLine & _
SHOW FOLDER NAMES HERE, "ENTER FOLDER NAME")
srcFile = myFld & "\" & Me.cboViewPO ' MyFld Would be come the result of input box Number selected
Application.FollowHyperlink SrcPath & srcFile
End If
End If

If We Add a Folder within the SrcPath so there is now 5 folders in there and not 4, can the input box now list 5 ?????

[Minty]

Use a list box, populate that with the folder names and run your code from the list box selection.

[moke123]

I agree with minty but thought I'd give it a shot.

try this

[DMT Dave]

heyyy thank you guy's will give it a go

[moke123]

BTW, I copied and pasted some of the code for the example but made changes to it.
Even though one procedure is named RecursiveSearchFolders it is not recursive. I was too lazy to change its name.
It didn't appear you were concerned with subfolders.
I also didn't add error handling for instance if they enter a 7 and there are only 6 folders.

edit: Now that I'm looking at it again I see a few changes that can be made and still accomplish the same thing thing with a little less code.

heres the changes:

Option Compare Database
Option Explicit


Dim dict As New Scripting.Dictionary


Private Sub Command2_Click()


    Me.Text0 = FSBrowse(, msoFileDialogFolderPicker)    'get the top folder


End Sub


Private Sub Command3_Click()


    Dim strMsg As String
    Dim x As Variant


    If Nz(Me.Text0, "") = "" Then Exit Sub


    Call RecursiveSearchFolders(Me.Text0, strMsg) 'populate the dictionary and get the strMsg (strMsg passed ByRef)


    x = InputBox(strMsg, "Select a Folder Number")
    
    If x > dict.Count Then Exit Sub  'if number entered is higher than folder count exit sub


    If Nz(x, "") <> "" Then
    
        Application.FollowHyperlink dict.Item(x)
        
    End If


End Sub


Sub RecursiveSearchFolders(fld As String, ByRef strMsg As String)


    dict.RemoveAll  'clear dictionary


    Dim fold As Folder
    Dim fldr As Folder
    Dim i As Integer


    i = 1


    Dim fso As New FileSystemObject


    Set fldr = fso.GetFolder(fld)


    For Each fold In fldr.SubFolders


        dict.Add CStr(i), CStr(fold.Path)   'add number (i) as index and Folder path as item to dictionary
        
        strMsg = strMsg & i & Chr(9) & fold.Name & vbNewLine 'add number and folder name to strMsg


        i = i + 1


    Next


End Sub

Also note you need a reference to MS scripting runtime and MS office XX object library.