Properties vbCrlf and CHR(13) & CHR(14) to create into a List into a Textbox

[charly.csh]

Hi everyone

I hope somebody could help me with this...
I'm writing into a textbox with my code a "List of people" depending on some Checkboxes. (The name of the textbox is TeamWorktxt) and the checkboxes are WT_Quality, WT_Production, WT_Warehouse, WT_Process.

If I l click on one it adds the name of the guy responsible of the "area" and after this addition I am also using the VbCrLf to "create" an "Enter" effect... it gives the appearance into the big textbox like a "list"

The issue is when unclick on this check box an use the property REPLACE and CHR(10) or CHR(13) it deletes all the "blank" spaces and the list lose its structure. What I want is just to clean the line created or "undo" my "Enter"



I do not know if there is just a property to eliminate just a "line" and not all the blank spaces

I highly appreciate your support


(My access app is to record customer complaints. In this textbox is just added people that participate into the problem solution of this specific complaint, I mean my main table has diffente fiels like ID, Date_Start, Date_End, Issue_Reported, and some more... one of this is "TeamWork" which include the "names of the people" working on that specific issue; such are not really important data to query further, is just to "know" who were working on it)


My code

'****************************************
Private Sub WT_Quality_Click()

If Me.WT_Quality = -1 And Len(Me.TeamWorktxt & vbNullString) = 0 Then

Me.TeamWorktxt = DLookup("[Name]", "[TeamWork]", "[Department]= 'Quality'")

ElseIf Me.WT_Quality = -1 And Me.TeamWorktxt <> "" Then

Me.TeamWorktxt = Me.TeamWorktxt & vbCrLf & DLookup("[Name]", "[TeamWork]", "[Department]= 'Quality'")

End If

If Me.WT_Quality = 0 Then

Dim Quality As String
Quality = DLookup("[Name]", "[TeamWork]", "[Department]= 'Quality'")

'Here is my issue, I am sure if this is the best way to do this...

Me.TeamWorktxt = Replace(Me.TeamWorktxt, Quality, "")
Me.TeamWorktxt = Replace(Me.TeamWorktxt, Chr(10), "") 'Chr(10)
Me.TeamWorktxt = Replace(Me.TeamWorktxt, Chr(13), "") 'Chr(13)

End If

End Sub

'Enclosed is the example... I hope somebody could help
Example of database list.zip

[davegri]

Try this.
It replaces the entire code behind the form.

Edit: found a bug. See red code at bottom.

Option Compare Database
Option Explicit

Private Sub WT_Quality_Click()
    Dim Quality As String
    Quality = DLookup("[Name]", "[TeamWork]", "[Department]= 'Quality'")
    If Me.WT_Quality = -1 And Len(Me.TeamWorktxt & vbNullString) = 0 Then
        Me.TeamWorktxt = Quality
    ElseIf Me.WT_Quality = -1 And Me.TeamWorktxt <> "" Then
        Me.TeamWorktxt = Me.TeamWorktxt & vbCrLf & Quality
    End If
    If Me.WT_Quality = 0 Then
        If InStr(Me.TeamWorktxt, vbCrLf & Quality) > 0 Then
            Me.TeamWorktxt = Replace(Me.TeamWorktxt, vbCrLf & Quality, "")
        ElseIf InStr(Me.TeamWorktxt, Quality) > 0 Then
            Me.TeamWorktxt = Replace(Me.TeamWorktxt, Quality, "")
        End If
        Call Blankit
    End If
End Sub


Private Sub WT_Process_Click()
    Dim Process As String
    Process = DLookup("[Name]", "[TeamWork]", "[Department]= 'Process'")
    If Me.WT_Process = -1 And Len(Me.TeamWorktxt & vbNullString) = 0 Then
        Me.TeamWorktxt = Process
        ElseIf Me.WT_Process = -1 And Me.TeamWorktxt <> "" Then
        Me.TeamWorktxt = Me.TeamWorktxt & vbCrLf & Process
    End If
    
    If Me.WT_Process = 0 Then
        If InStr(Me.TeamWorktxt, vbCrLf & Process) > 0 Then
            Me.TeamWorktxt = Replace(Me.TeamWorktxt, vbCrLf & Process, "")
        ElseIf InStr(Me.TeamWorktxt, Process) > 0 Then
            Me.TeamWorktxt = Replace(Me.TeamWorktxt, Process, "")
        End If
        Call Blankit
    End If
End Sub


Private Sub WT_Production_Click()
    Dim Production As String
    Production = DLookup("[Name]", "[TeamWork]", "[Department]= 'Production'")
    If Me.WT_Production = -1 And Len(Me.TeamWorktxt & vbNullString) = 0 Then
        Me.TeamWorktxt = Production
        ElseIf Me.WT_Production = -1 And Me.TeamWorktxt <> "" Then
        Me.TeamWorktxt = Me.TeamWorktxt & vbCrLf & Production
    End If
    If Me.WT_Production = 0 Then
        If InStr(Me.TeamWorktxt, vbCrLf & Production) > 0 Then
            Me.TeamWorktxt = Replace(Me.TeamWorktxt, vbCrLf & Production, "")
        ElseIf InStr(Me.TeamWorktxt, Production) > 0 Then
            Me.TeamWorktxt = Replace(Me.TeamWorktxt, Production, "")
        End If
        Call Blankit
    End If
End Sub


Private Sub Blankit()
    If WT_Production = 0 And WT_Quality = 0 And WT_Process = 0 Then
        Me.TeamWorktxt = ""
    End If
    If Left(Me.TeamWorktxt, 2) = vbCrLf Then
        Me.TeamWorktxt = Replace(Me.TeamWorktxt, vbCrLf, "", 1, 1)
    End If
End Sub

[Uncle Gizmo]

You put the team worker participants "names of the people" in a separate table like attached. Using a subform on the main form to store the "names of the people"

[charly.csh]

Good alternative!!