How to do filtering for each field individually, but through one procedure?

[acces6897]

How to do filtering for each field individually, but through one procedure?
There is:
- tape form;
- two fields for filtering.
I made the code but it does not work.

Private Sub NameStudCritFltr_txt_Change()

    Dim nameField
    nameField = "NameStud"
    FltrStart (nameField)
End Sub

Private Sub Property_2CritFltr_txt_Change()
    Dim nameField
    nameField = "Property_2"
    FltrStart (nameField)
End Sub

Public Sub FltrStart(nameField)
    Dim cntrl As Control

      Set cntrl = Screen.ActiveControl

    If cntrl.Text & "" <> "" Then
         ' Использование фильтра
         Me.Filter = nameField & " like '*" & cntrl.Text & "*'" '
         Me.FilterOn = True
     Else
        Me.FilterOn = False
     End If
        Me(cntrl.Name).SetFocus
        Me(cntrl.Name).SelStart = Len(Me(cntrl.Name).Text) + 1
 End Sub

Фильтр.zip

[ArviLaanemets]

1. Use Update event (is fired when control loses focus) instead of Change (is fired whenever anything n control changes - e.g. a character is entered);
2. The event code for both textboxes will be identical:
A string variable must be declared;
If ... elseif ... else ... endif is used to compose the filter string in defined variable in following order
a) if both textboxes are empty (no filter);
b) if name texbox is empty (filtering by property_2;
c) if property_2 texbox is empty (filtering by name);
d) else filtering by name and property_2;
The filter condition for form is applied.

[acces6897]

@ArviLaanemets
1. I need the filtering to occur as you type in the filter.
I could be wrong, but the Update event does not allow this.
So leave the event "Change"?
2. In connection with the above, paragraph 2 of your decision remains unchanged?
3. I am worried about this part of the code.

Me(cntrl.Name).SetFocus
Me(cntrl.Name).SelStart = Len(Me(cntrl.Name).Text) + 1

Did I do the right thing?
4. Or is the solution itself incorrect and do I need to create a separate filter for each field?

[accesstos]

Give a try to this code:

Private Sub txtFromCityName_Change()
    FltrStart "NameStud"
End Sub

Private Sub txtToCityName_Change()
    FltrStart "Property_2"
End Sub

Private Sub FltrStart(strField As String)
    Dim strText As String

    On Error Resume Next
    With Screen.ActiveControl
        strText = .Text
        Me.Filter = "[" & strField & "] LIKE ""*" & strText & "*"""
        Me.FilterOn = Len(strText) > 0
        .SetFocus
        .SelStart = Len(strText) + 1
    End With
End Sub

Edit:
If you don't want to pass the name of the field as argument, you have to keep it in the Tag property of the search control.
Then, the code above could be as follows:

Private Sub txtFromCityName_Change()
    FltrStart
End Sub

Private Sub txtToCityName_Change()
    FltrStart
End Sub

Private Sub FltrStart()
    Dim strText As String

    On Error Resume Next
    With Screen.ActiveControl
        strText = .Text
        Me.Filter = "[" & .Tag & "] LIKE ""*" & strText & "*"""
        Me.FilterOn = Len(strText) > 0
        .SetFocus
        .SelStart = Len(strText) + 1
    End With
End Sub

[mike60smart]

Hi

Your table structure is wrong.

1 Student has Many Properties.

You need a table for Students and another table for StudentsProperties

[ArviLaanemets]

@ArviLaanemets
1. I need the filtering to occur as you type in the filter.

Why do you want this?

E.g. you want to search for students with name John. You type "J", and Change event fires. Te form is filtered for students with name J. No one is found (or when yo use LIKE all students with "J" in name will returned. Probably some additional events are fired (BeforeUpdate, AfterUpdate, Current etc.). You type next letter, and the same chain is happening with "Jo" as search string. Etc. Btw. such thing is named "cascading events" and is considered to be avoided.

[moke123]

To reinforce what mike said, It is usually a tell tale sign of poor table design when you have fields like Property1,Property2,Property3.
What do these properties represent?

[June7]

Review http://allenbrowne.com/AppFindAsUType.html