Format decimal numbers with fixed width

[Persist]

Hello



How can I format a decimal number so that:
. the width of the whole number is 10 characters
. 2 digits always after the decimal point
. for positive and negative numbers

Format(34.5, “ ###0.00”) gives 34.50
This varies the number of spaces to the left of decimal point

Format(34.5, “ 0000.00”) gives 0034.50
This gives a fixed width but not for negative numbers and it looks ugly

I want to print tables and have the columns line up
For example (I hope the numbers below do line up)
Number1 Number2
-12.30 102.70
4.50 -300.50

[dsmacs]

What about printing from a contionous form or report and right aligning the field and changed to fixed?

[Persist]

I am printing to a text file

Print #1, Format(Number1,"##0.00"), Format(Number2, "##0.00")
so I would like some function to do suitable formatting for me.

[NoellaG]

Hi,

you could use the format$ function to have a text string as result and then use the space function to add the necessary number of spaces in front of the formatted number.
for instance to get a string of 10 chars:
Space$(10- len(Format$(Number1,"##0.00"))) & Format$(Number1,"##0.00")

[Persist]

Thanks for your neat suggestion.
Based on it, I wrote the following function.
It may well have some flaws - but the results are easier to see now.

Function MyFmt(aNum As Double, Width As Integer) As String
' Function to format a number with
' two digits after decimal pont
' a width of Width characters including the sign
' I think Width should be greater than 13 + 1 for a sign = 14
Dim nSpaces As Integer
Dim aString As String
aString = Format$(aNum, "##,###,##0.00")
nSpaces = Width - Len(aString)
If nSpaces < 0 Then
nSpaces = 0
End If
MyFmt = Space$(nSpaces) & aString
End Function

I am suprised that VB does not contain something like this or more powerful. The old language FORTRAN did it.

Thanks again.

[Persist]

I have improved this formatting function
Can people see any way to make this more efficient

Function MyFmt(aNum As Double, Width As Integer, nDig As Integer) As String
' Function to format a number controlling width with:
' aNum: the number to be presented as a string
' Width: the minimum width of the string including any sign
' nDig: the number of digits after the decimal point
Dim nSpaces As Integer
Dim aString As String
Dim strFmt As String

strFmt = "##,###,##0"
If nDig > 0 Then
strFmt = strFmt & "."
For nSpaces = 1 To nDig
strFmt = strFmt & "0"
Next nSpaces
End If ' nDig

aString = Format$(aNum, strFmt)
nSpaces = Width - Len(aString)
If nSpaces < 0 Then
nSpaces = 0
End If
MyFmt = Space$(nSpaces) & aString
End Function