References in Access 2010

[RayMilhon]

If I look at the References under Tools in MS Access 2010. I have 6 that are checked. I'm trying to validate the user's machines because the database works perfectly on my machine but there are various errors on everyone else's machine. I want to double check that each computer has the same reference libraries linked. The problem is that when I open the References window the form is too small to display the full path of each reference. There are 2 that are larger than what's visible. There is no window expansion functionality in that window. How do I see the entire path for all 6 references?

[June7]

Not sure what you mean by 'path' - you mean the full name listed in Available References? Maybe use the horizontal scroll bar?

[orange]

Ray,

Here's some older vba that may help.

'---------------------------------------------------------------------------------------
' Procedure : Get_References_In_This_Project
' Author    : user
' Date      : 2/18/2009
' Purpose   : List the references in the VBA Project and indicate where
'the reference is OK or Is Broken (Missing)
' Get the name, description, full path and "Missing/Broken" for each reference
'---------------------------------------------------------------------------------------
'
Sub Get_References_In_This_Project()
      Dim refIsBroken As String

      'Loop thru each reference in this VBA Project
10    For Each ref In Application.VBE.ActiveVBProject.References
20        refIsBroken = "OK"
      ' Get the Reference Name
30    refname = ref.name
40    refDesc = ref.Description
50    refPath = ref.FullPath
      'Return True/False  indicating if Reference link is broken: True(Ref is missing) or False (Ref OK)
60        If ref.IsBroken = True Then
70            refIsBroken = "***Missing/Broken***"
80        Else
90        refIsBroken = "OK"
100       End If
110   Debug.Print refname & ":  " & refDesc & " - " & refPath & " -> " & refIsBroken
120   Next ref

End Sub

[RayMilhon]

In the above image you'll see towards the top which reference is checked below that is the file path to where the file is located and the name of the file. The space available is insufficient to display the full path.

I will try that code block on Monday and let you know.

[June7]

Oh, duh! I've never even noticed that and right in my face, even when I looked at References after reading your post. Yep, have to use code. Tried and it works. But I had to disable Option Explicit.

[RayMilhon]

Thanks June7 that worked perfectly. I did make the following adjustment Added The Dim statement: Dim ref as Variant, Refname as String, refDesc as string, refpath as string That allowed me to leave the Option Explicit active.

Sub Get_References_In_This_Project()
      Dim refIsBroken As String
      Dim ref As Variant, Refname As String, refDesc As String, refPath As String
      'Loop thru each reference in this VBA Project
    For Each ref In Application.VBE.ActiveVBProject.References
        refIsBroken = "OK"
      ' Get the Reference Name
    Refname = ref.Name
    refDesc = ref.Description
    refPath = ref.FullPath
      'Return True/False  indicating if Reference link is broken: True(Ref is missing) or False (Ref OK)
        If ref.IsBroken = True Then
            refIsBroken = "***Missing/Broken***"
        Else
        refIsBroken = "OK"
       End If
   Debug.Print Refname & ":  " & refDesc & " - " & refPath & " -> " & refIsBroken
   Next ref

End Sub

[June7]

Yeah, I tried Dim ref as Reference, didn't like that, should have known to try Variant. Glad you got it working.