Export Report to PDF with Button

[June7]

If the folder doesn't already exist, need to create it first.

MyPath = "C:\TestFolder\" & Me.Client_Name


If Dir(MyPath)="" Then
MkDir(MyPath)
End If
MyFilename = Format(Me.Job_Date, "yyyy-ddmm") & "_" & Now() & ".pdf"
DoCmd.OutputTo acOutputReport, , acFormatPDF, MyPath & "\" & MyFilename

[ItsMe]

...I'm just wondering now how can I make it so it doesn't overwrite files with the same name how can i successfully add the time function to the filename to do this?...

You could incorprate a string variable that has a timestamp. Here is one example.

dim strTimeStamp as string
strTimeStamp = Format(Now(), "mmddyyhhss")

Sometimes I want to be able to read the timestamp

strTimeStamp = Format(Now(), "mm_dd_yy_hh_ss")

With that you can concatenate strTimeStamp.

[agure]

If the folder doesn't already exist, need to create it first.

MyPath = "C:\TestFolder\" & Me.Client_Name
If Dir(MyPath)="" Then
MkDir(MyPath)
End If
MyFilename = Format(Me.Job_Date, "yyyy-ddmm") & "_" & Now() & ".pdf"
DoCmd.OutputTo acOutputReport, , acFormatPDF, MyPath & "\" & MyFilename

This Worked the first time but the second time I run the exact same invoice it gives me a Path/File access error

[ItsMe]

Post the code you used.

[agure]

Post the code you used.

This worked well the first time when im creating a folder for each Client Name but I think there is a problem with the IF statement

I also tried it exactly how you had it written

Dim MyFilter As String
Dim MyPath As String
Dim MyFilename As String
Dim strTimeStamp As String


MyFilter = "[Invoice#] = '" & [Forms]![Job List (New Job) Form]![Invoice#] & "'"




MyPath = "C:\TestFolder\" & Me.Client_Name
If Dir(MyPath) = "" Then
MkDir (MyPath)
End If


strTimeStamp = Format(Now(), "mm_dd_yyyy___@hh_mm")




MyFilename = "Invoice#" & Me.Invoice_NO_ & "_" & strTimeStamp & ".pdf"




Debug.Print MyPath
Debug.Print MyFilename

DoCmd.OpenReport "Final Invoice Report", acViewPreview, , MyFilter
DoCmd.OutputTo acOutputReport, "Final Invoice Report", acFormatPDF, MyPath & "\" & MyFilename, True
DoCmd.Close acReport, "Final Invoice Report"

[agure]

You could incorprate a string variable that has a timestamp. Here is one example.

dim strTimeStamp as string
strTimeStamp = Format(Now(), "mmddyyhhss")

Sometimes I want to be able to read the timestamp

strTimeStamp = Format(Now(), "mm_dd_yy_hh_ss")

With that you can concatenate strTimeStamp.

This string worked really well thank you. !

[agure]

Now my final concern

MyPath = "C:\TestFolder\" & Me.Client_Name
If Dir(MyPath) = "" Then
MkDir (MyPath)
End If

This works only the first time I execute for a new client name so i get the new folder. The second time i execute this I receive an error at MkDir(MyPath) any help guys? It is running the If statement when I don't want it to because the folder has already been created.

[agure]

Instead of :

MyPath = "C:\TestFolder\" & Me.Client_Name
If Dir(MyPath) = "" Then
MkDir (MyPath)
End If

I used:

On Error Resume NextMkDir MyPath
On Error GoTo 0

My final Code

Private Sub Command72_Click() 
Dim MyFilter As String
Dim MyPath As String
Dim MyFilename As String
Dim strTimeStamp As String


MyFilter = "[Invoice#] = '" & [Forms]![Job List (New Job) Form]![Invoice#] & "'"




MyPath = "C:\TestFolder\" & Me.Client_Name


On Error Resume Next
MkDir MyPath
On Error GoTo 0


strTimeStamp = Format(Now(), "mm_dd_yyyy___@hh_mm")




MyFilename = "Invoice#" & Me.Invoice_NO_ & "_" & strTimeStamp & ".pdf"




Debug.Print MyPath
Debug.Print MyFilename
                
DoCmd.OpenReport "Final Invoice Report", acViewPreview, , MyFilter
DoCmd.OutputTo acOutputReport, "Final Invoice Report", acFormatPDF, MyPath & "\" & MyFilename, True
DoCmd.Close acReport, "Final Invoice Report"




End Sub

Thank you everyone for your help, I used bits and pieces from everyone and got exactly what I needed, thanks alot !!!!

[ItsMe]

You can do your directory validation like this.

If Dir(MyPath, vbDirectory) = "" Then
MkDir (MyPath)
End If

I had to look at some of my code snippits...

[agure]

You can do your directory validation like this.

If Dir(MyPath, vbDirectory) = "" Then
MkDir (MyPath)
End If

I had to look at some of my code snippits...

Thanks for looking back, I tried this one too works just as good. Gotta love VBA more than one way to do stuff lol.