I slightly misunderstood your question. But here is some example VBA code that should get you started. As I don't have all the details of your database this is entirely untested and I can't vouch for this being bug free.
Code:
Private Sub AssignIncompleteResponsibilities()
On Error GoTo ErrHandler
Dim rs As DAO.Recordset
Dim qry As String
Dim users() As Long 'An array to hold user IDs that you want to assign tasks to
Dim user_index As Long 'track which user we're assigning tasks to
'*********************************************************************************************
'YOU NEED A METHOD TO POPULATE THE users() ARRAY WITH THE USER IDS YOU WANT TO ASSIGN TASKS TO
'THIS CAN BE A HARD CODED LIST, ANOTHER VBA FUNCTION, A PARAMETER ARGUMENT, ANOTHER QUERY
ReDim users(1 To 6)
users(1) = 1
users(2) = 3
users(3) = 4
users(4) = 12
users(5) = 15
users(6) = 7
'*********************************************************************************************
user_index = 1 'start at one for base 1 array, or 0 for base 0 array, etc.
'Query all the records with an incomplete status.
'Careful, using this particular query will reassign responsibilities that have already been assigned. I'm not sure that's what you wanted or not?
qry = "SELECT [Assigned To] FROM [Responsibility] WHERE [Status]='Incomplete';"
'Load the query
Set rs = CurrentDb.OpenRecordset(qry, dbOpenDynaset)
'Make sure we actually found records or we'll get errors
If Not (rs.BOF And rs.EOF) Then
'This line probably redundant but can't hurt
rs.MoveFirst
'Loop through each of the records from the query
Do While Not rs.EOF
rs.Edit
rs![Assigned To] = users(user_index)
rs.Update
user_index = user_index + 1 'move on to assign to the next user in the users array
If user_index > UBound(users) Then user_index = 1 'roll back to the first user if we just assigned to the last user in the users array
'Move on to the next incomplete task, rinse and repeat
rs.MoveNext
Loop
End If
'always close your objects
rs.Close
ExitHandler:
'release your object variable
Set rs = Nothing
Exit Sub
ErrHandler:
MsgBox Err.Description, vbExclamation, "Error Reassigning Tasks #" & Err.Number
Resume ExitHandler
End Sub
This will find all records with Incomplete status. You said incomplete or "blank". Do you mean Null? Does your [status] field allow for zero length strings? Would you want this work on all Incomplete/null tasks or just Incomplete/Null tasks that are also unassigned? For example:
Code:
qry = "SELECT [Assigned To] FROM [Responsibility] WHERE ([Status]='Incomplete' OR [Status] Is Null) AND [Assigned To] Is Null;"