Close Form Code

[swenger]

Hi,

I have a form which has a few buttons to print. I want that when someone clicks a button it prints a report but then closes the form. my code seems to close the print window but not the form. See my original code below. I tried changing the close section to the following but got a type mismatch

Dim stDocName As String
stDocName = "frmMenuLabelPrnt"
DoCmd.close stDocName

Private Sub Print_Click()
On Error GoTo Print_Click_Err


If Frame16 = 1 Then
    DoCmd.OpenReport "PackingCard1", acViewPreview, "", "", acNormal
    DoCmd.RunCommand acCmdPrint
Else
If Frame16 = 2 Then
    DoCmd.OpenReport "PackingCard2", acViewPreview, "", "", acNormal
    DoCmd.RunCommand acCmdPrint
Else
End If
End If


DoCmd.close


Print_Click_Exit:
    Exit Sub


Print_Click_Err:
    MsgBox Error$
    Resume Print_Click_Exit


End Sub

[pbaldy]

You have to specify the object type first. Look at the arguments for Close.

[andy49]

Docmd.close acform “formname” ??

[swenger]

That worked. However the Report still stays open which I am guessing is from

 DoCmd.OpenReport "PackingCard1", acViewPreview, "", "", acNormal

I tried the following

stDocName = "PackingCard1"
DoCmd.close acReport, stDocName

but the message is the this object is not open

Can I print the report without running the line in the code to acpreview first?

[pbaldy]

Just delete acViewPreview and the report will print to the default printer.

[swenger]

Thanks for your help

[pbaldy]

No problem.

[ssanfu]

Private Sub Print_Click()

Be aware that "Print" is a reserved word in Access and shouldn't be used for object names.

I modified your code a little.....

Private Sub btnPrint_Click()
    On Error GoTo Print_Click_Err
    Dim ReportName As String

    ReportName = ""

    Select Case Me.Frame16
        Case 1
            ReportName = "PackingCard1"
        Case 2
            ReportName = "PackingCard2"
    End Select

    If ReportName = "" Then
        MsgBox "No report selected"
    Else
        DoCmd.OpenReport ReportName, , , , acNormal
        DoCmd.RunCommand acCmdPrint
    End If

    DoCmd.Close acForm, Me.Name

Print_Click_Exit:
    Exit Sub

Print_Click_Err:
    MsgBox Error$
    Resume Print_Click_Exit

End Sub