Title: Giving Wrong Name

[netchie]

When entering data, I chose a name from the list and I can either view what I've added for that person or enter new data. The word "View" and "New" is clickable on the form. View to see the complete info for that person and New to input a new information for that person.

When I clicked New, a new form will pop up (frmCertificationEdit) showing all info and the title has "Recertification Details for " and the name of the person. When I clicked View same form is showing (frmCertificationEdit) but for some reason the title stays to wrong name even if the name I chose is different. I'm using same form for both View and New but why is it when I clicked View, the name of the person don't change to whoever I chose from the list?

Here's the Event Procedure in On Click:


Private Sub Edit_Click()
On Error GoTo Err_Edit_Click


Dim stDocName As String
Dim stLinkCriteria As String
Dim tempStr As String

stDocName = "frmCertificationEdit"
If Me.Edit.Value = "NLN" Then
MsgBox "This item has been flagges as 'No Longer Needed'.", vbExclamation + vbOKOnly
GoTo Exit_Edit_Click
ElseIf Me.Edit.Value = "View" Then
modMain.certificateCount = Me.tbCertificationCount.Value
stLinkCriteria = "1=1" & " AND " & "tblCertifications.[CertDateID] = " & Me.CertDateID.Value & ""
DoCmd.OpenForm stDocName, acNormal, , stLinkCriteria
ElseIf Me.Edit.Value = "New" Then
modMain.certificateCount = Me.tbCertificationCount.Value
DoCmd.OpenForm stDocName, acNormal, , , acFormAdd
If IsNull(Form_frmCertifications.cbFullName.Column(1) ) Then
tempStr = Form_frmCertifications.cbFullName.Value & ", " & Form_frmCertifications.tbFirstName
Else
tempStr = Form_frmCertifications.cbFullName.Column(1) & ", " & Form_frmCertifications.tbFirstName
End If
Form_frmCertificationEdit.cbempid.Locked = False
Form_frmCertificationEdit.cbempid.Text = tempStr
Form_frmCertificationEdit.labelTitle.Caption = "Recertification Details for " & tempStr
Form_frmCertificationEdit.cbCertDepartment = Form_frmCertifications.empdept.Column(0)
Form_frmCertificationEdit.cbcertSupervisor = Form_frmCertifications.empSupervisor
Form_frmCertificationEdit.cbCertDepartment.SetFocu s
Form_frmCertificationEdit.cbempid.Locked = True
End If
Exit_Edit_Click:
Exit Sub
Err_Edit_Click:
MsgBox Err.Description
Resume Exit_Edit_Click
End Sub

Your help is appreciated.

Thanks,
netchie

[June7]

Did you step debug? Set breakpoint, follow code as it executes. Find where it deviates from expected behavior, fix, debug again.

[ssanfu]

In looking at the code, you never assigned a value for "tempSt" in the ELSEIF Me.Edit = "View" clause. I don't know it this will run correctly, but I modified your code.

Private Sub Edit_Click()
   On Error GoTo Err_Edit_Click
   Dim stDocName As String
   Dim stLinkCriteria As String
   Dim tempStr As String

   stDocName = "frmCertificationEdit"
   If Me.Edit.Value = "NLN" Then
      MsgBox "This item has been flagges as 'No Longer Needed'.", vbExclamation + vbOKOnly

   ElseIf Me.Edit = "View" Then
      modMain.certificateCount = Me.tbCertificationCount
      stLinkCriteria = "1=1" & " AND " & "tblCertifications.[CertDateID] = " & Me.CertDateID
      DoCmd.OpenForm stDocName, acNormal, , stLinkCriteria

      If IsNull(Forms!frmCertifications.cbFullName.Column(1)) Then
         tempStr = Forms!frmCertifications.cbFullName & ", " & Forms!frmCertifications.tbFirstName
      Else
         tempStr = Forms!frmCertifications.cbFullName.Column(1) & ", " & Forms!frmCertifications.tbFirstName
      End If

      Forms!frmCertificationEdit.labelTitle.Caption = "Recertification Details for " & tempStr
  
   ElseIf Me.Edit = "New" Then
      modMain.certificateCount = Me.tbCertificationCount
      DoCmd.OpenForm stDocName, acNormal, , , acFormAdd

      If IsNull(Forms!frmCertifications.cbFullName.Column(1)) Then
         tempStr = Forms!frmCertifications.cbFullName & ", " & Forms!frmCertifications.tbFirstName
      Else
         tempStr = Forms!frmCertifications.cbFullName.Column(1) & ", " & Forms!frmCertifications.tbFirstName
      End If

      Forms!frmCertificationEdit.cbempid.Locked = False
      Forms!frmCertificationEdit.cbempid = tempStr
      Forms!frmCertificationEdit.labelTitle.Caption = "Recertification Details for " & tempStr
      Forms!frmCertificationEdit.cbCertDepartment = Forms!frmCertifications.empdept.Column(0)
      Forms!frmCertificationEdit.cbcertSupervisor = Forms!frmCertifications.empSupervisor
      Forms!frmCertificationEdit.cbCertDepartment.SetFocus
      Forms!frmCertificationEdit.cbempid.Locked = True
   End If

Exit_Edit_Click:
   Exit Sub
Err_Edit_Click:
   MsgBox Err.Description
   Resume Exit_Edit_Click
End Sub

I also cleaned up some other things I saw: you don't need to add ".Value" as that is the default property.

You don't need the "GOTO" line because the code will 'fall through' to the the END IF and exit properly.


And the proper way (not the only way) to refer to other forms is:
Forms!formName.controlName, not "Form_frmCertificationEdit"

[June7]

Actually, in VBA code, both versions of referring to forms (as well as reports) will work. Access requires the Forms/Reports class and ! syntax.

[boblarson]

Best to NOT use the Form_ syntax though as it can have unintended side effects.

[netchie]

Thanks guys for checking this for me. You guys are always nice and ready to help users in need like me .

Thanks ssanfu for helping out. Yeah, it worked!

netchie